Service Bell というアイテム

お友達の店先の飾り＋実用も兼ねてサービスベルという受付などに置いてありそうなチーンっと鳴るあれの完成品を買ってみたけれど、中に入っているスクリプトがどうもスッキリしなくておそらくはオンラインチェッカー＋チップジャーっていう感じの何処にでもあるIMパネルを元に頑張って改造したのかなぁと思われるけれど変な所を直すよりは新規に作った方がよさそうだｗ　ってことで書いてみました。

変更してみた所は
・IMを送る動作を当人がオンラインの時だけに限定
・直前と同じアバターである場合はIMを送らない事（ただし６時間経過で再送信可とする）
・IMの送信先をオブジェクトのオーナー固定でなく指定のKEYでも処理可能にする

こんな Hallo world みたいな内容でもサンプルがないと分かりにくいのかな。
そんなスクリプトを弄るきっかけにでも、どうぞ～

//service bell for EV

//メッセージ送信先のUUID
key     IM_KEY = NULL_KEY;//Owner以外に送信するなら、ここにUUIDで記述してね
string  Touch_NAME= "";
key     Touch_KEY;
key     prev_key = NULL_KEY;
key     query_key;

default{
    touch_start(integer total_number){
        if(IM_KEY == NULL_KEY) IM_KEY = llGetOwner();
        if(llGetAndResetTime() > 2.0){//連打防止
            llPlaySound("Desk Bell1", 1.0);
            Touch_NAME = llDetectedName(0);
            Touch_KEY = llDetectedKey(0);
            query_key = llRequestAgentData(IM_KEY,DATA_ONLINE);
            llSetTimerEvent(6 * 60 * 60);//6時間後
        }
    }

    dataserver(key request_id, string data){
        if(request_id == query_key){
            if((integer)data){
                //ONLINE
                llSay(0,"The shop Owner Is Online And Has Been Informed That You Rang The Bell");
                if(Touch_KEY != prev_key) llInstantMessage(IM_KEY,Touch_NAME + " Rang The Service Bell");
            }else{
                //OFFLINE
                llSay(0,"The shop Owner Is Currently Offline");
            }
            //キーの置き換え
            prev_key = Touch_KEY;
            //クエリーキーを削除
            query_key = NULL_KEY;
        }
    }

    timer(){
        llSetTimerEvent(0.0);
        //キーの置き換え
        prev_key = NULL_KEY;
    }
}